Beginner's Tutorial

Again, this is not by me. This is re-posted from the old forums, but with minor edits.

RigidChips Beginner's Tutorial

This is a tutorial for people new to making RigidChips models. I will be walking through how to make a basic car from scratch using Notepad. [Fred: I believe that learning how to make a model from scratch using text only is the key to understanding how to use RCD and truly understanding how RigidChips models work.] I hope it helps. This tutorial may seem long, but that's only because of me explaining how each part of code works.

A RigidChips model has 3 basic parts. The values, keys and the body. First is the values.

Values

The values section is always at the first part of RigidChips model. This is what it will look like with nothing in it:

Code:

Val
{

}


In between the curly brackets is where you put all your 'values', or variables. These control what a vehicle does by controlling chips' attributes.

A basic car has 3 values: Engine, Brake and Steering. To add a value into the val section you put this into the val section:

Code:

valuename()

This will create a value using all the default properties.
To change properties you put them within the brackets. These are the properties that can be put in:

Default=<number>
The is what the number that the value starts as.
If it is: Engine(default=0) then engine will be 0 when you play rigidchips

Min=<number>
This is the lowest number that the value can get to.
If it is: Engine(min=100) then the engine will always be above 100 and won't be able to go below 100

Max=<number>
This is the maximum number that the value can get to.
If it is: Engine(max=100) then the engine will always be under 100 and never over.

Step=<number>
The value will add or subtract the step to get back to the default.
If it is: Engine(step=1) and engine is at 1000, then it will take 1000 frames to get back to 0

Disp=0
If disp is 0 than the value won't appear in the values list in RigidChips.

So if a car has 3 main values, Engine, Brake and Steering, we need to add them in. The engine val should be something like this:

Code:

Engine(default=0,min=-3000,max=5000,step=1000)


For the engine, the value will apply to the power that the wheels have. Cars need to be able to go backwards, just not as fast so that's why the minimum is negative and is less power than the maximum.

Now that we have the engine, we can start with the brakes. The brakes should go up to the maximum quickly because brakes in real cars don't slowly start putting more and more pressure to stop the car. The brake val should be like this:

Code:

Brake(default=0,min=0,max=100,step=50)

There's no need for brakes to stop it backwards so we don't need a negative value for the minimum. The maximum could be over 100 but we can leave it at 100 until we start making the car. The step is 50 because we want the brakes to stop as soon as we release the button.

Last is the steering. The steering will be different because it's not referring to how much power. It's referring to an angle. It should look like this:

Code:

Steering(default=0,min=-15,max=15,step=1)

The default is 0 because you want the wheels at no angle when you're not pressing buttons. The minimum is at negative 15 and the maximum at 15 because you want the wheels to turn in opposite directions when you press the buttons to steer. The step is 1 because you want the steering to go back to 0 fast, but not instantly when not pressing buttons.

Now that the values are done, we can go onto the keys section.

Keys

The keys section is just about making values bigger or smaller depending on what key in pressed. Like the val section, for the key section everything is in the key curly brackets. An empty key section looks like this:

Code:

Key
{

}

In most games, the arrow keys control the movement of the car. Up and down keys control the engine and the left and right keys control the steering. This is how to make the engine value rise when pressing the up key:

Code:

0:Engine(step=500)

The number at the beginning refers to which key is pressed.
Click here for a list of the keys and the codes that go with them
The colon separates the key code from the name of the value, in this case, engine. The step in the brackets is how much it goes up by every frame that the key is held down. Now we need to make the engine power go down when the down key is pressed. The code for the down key is 1 so it will look like this:

Code:

1:Engine(step=-500)

The code for the steering and brake will be mostly the same:

Code:

2:Steering(step=-0.5)
3:Steering(step=0.5)
4:Brake(step=50)

The key code 4 is the letter z on the keyboard so when z is pressed, brake value will go up.

Now since the val and key sections are done, it should look like this:

Code:


Val
{
Engine(default=0,min=-3000,max=5000,step=1000)
Brake(default=0,min=0,max=100,step=50)
Steering(default=0,min=-15,max=15,step=1)
}
Key
{
0:Engine(step=500)
1:Engine(step=-500)
2:Steering(step=-0.5)
3:Steering(step=0.5)
4:Brake(step=50)
}

Now we start building the model.

Body

Before building a model, it's a good idea to plan which chips you're going to use and how you're going to build it.

The body section looks like this:

Code:


Body {
Core(){

}
}

It will always be like this with the core(){ directly below the the Body {. There will also always be two of } at the end of the section. If there aren't, you will most likely get an error.

The core chip is the chip that the models based off of. Every other chip in the model is attached to that chip in some way. To attach other chips to the core chip you put this code in between the core curly brackets:

Code:


N:Chip(){
}

This will attach a chip to the top of the core chip. The letter at the beginning stands for the 4 directions, North, South, East and West. The colon separates the direction from the chip type. There are a couple types of chips we'll be using in this model. Chip, Frame, Rudder, Wheel and Trim. Chip is just the normal kind of chip. Frame is the same except it isn't affected by air resistance. Rudder is the same as chip, except its angle uses a different axis. Wheel is a wheel. Trim is the same as rudder except its angle uses a different axis than rudder and chip.

First on the model, we'll start with the south part of it. Add this to the inside of the core:

Code:


S:Chip(){

}

This will create a chip going coming from the bottom side of the core chip. Next we'll put two trim chips going on east and west of that new chip we added. It will look like this:

Code:


S:Chip(){
E:Trim(){
}
W:Trim(){
}
}

I used trim chips instead of normal chips because you need a type of spoiler on your car. If not, then the car will take off slightly from the ground once it reaches certain speeds. The trim chips will use air resistance to push itself onto the ground give it more traction.

But there's one problem. The trim chips are straight so they aren't acting as spoilers. To fix this you need to add an angle to the trim chips. To do this, add angle=<Degrees> into the the brackets of the trim chips like this:

Code:


S:Chip(){
E:Trim(angle=-25){
}
W:Trim(angle=25){
}
}

The angles are opposite because they are on opposite sides of the model, East and West. If they were both the same angle then one would lift the model and one would press it down to the ground.

Now lets add the wheels. First, to make the car better, you should add shock absorbers to stop the model from being really stiff. To do this, we'll add frame peices to the trim pieces. Like this:

Code:


S:Chip(){
E:Trim(angle=-25){
N:Frame(angle=145,damper=0.07,spring=0.07){
}
}
W:Trim(angle=25){
N:Frame(angle=145,damper=0.07,spring=0.07){
}
}
}

The damper and spring properties of the chip will make it act like a shock absorber. The damper property is how much force it takes to move the chip. The spring property is how fast it springs back to its original position. Now we will add the wheels. The wheels angle will be -90. This will make it point to the ground. It will be like this:

Code:


S:Chip(){
E:Trim(angle=-25){
N:Frame(angle=145,damper=0.07,spring=0.07){
E:Wheel(angle=-90,power=-Engine,brake=Brake){

}
}
}
W:Trim(angle=25){
N:Frame(angle=145,damper=0.07,spring=0.07){
W:Wheel(angle=-90,power=Engine,brake=Brake){

}
}
}
}

The power=engine will make the power of the wheel spinning equal to the value, engine. When the up keys pressed, the value, engine, rises which will now make the wheel spin. If you notice, the east wheel has Engine, when the west wheel has negative engine. This is because of the same reasons as before with the angles of trim being opposite. Brake=Brake just sets the brake of the wheels to equal the value brake.

Now we will add the front of the model. This is easy because we've done all the coding for the back, so we can just copy it to the front. First we'll put 2 chips to the north like this:

Code:


S:Chip(){
E:Trim(angle=-25){
N:Frame(angle=145,damper=0.07,spring=0.07){
E:Wheel(angle=-90,power=-Engine,brake=Brake){

}
}
}
W:Trim(angle=25){
N:Frame(angle=145,damper=0.07,spring=0.07){
W:Wheel(angle=-90,power=Engine,brake=Brake){

}
}
}
}

N:Chip(){
N:Rudder(angle=steering){

}
}

For the second chip, rudder, the angle is equal to the value of steering. So that means when the left or right arrow keys are pressed, the angle is changed. The wheels will be attached to the rudder chip, so the angle of the wheels will be changed too. To add the wheels, we can just copy the bottom part with the other wheels. It will look like this:

Code:


S:Chip(){
E:Trim(angle=-25){
N:Frame(angle=145,damper=0.07,spring=0.07){
E:Wheel(angle=-90,power=-Engine,brake=Brake){

}
}
}
W:Trim(angle=25){
N:Frame(angle=145,damper=0.07,spring=0.07){
W:Wheel(angle=-90,power=Engine,brake=Brake){

}
}
}
}

N:Chip(){
N:Rudder(angle=steering){

E:Trim(angle=-25){
N:Frame(angle=145,damper=0.07,spring=0.07){
E:Wheel(angle=-90,power=-Engine,brake=Brake){

}
}
}
W:Trim(angle=25){
N:Frame(angle=145,damper=0.07,spring=0.07){
W:Wheel(angle=-90,power=Engine,brake=Brake){

}
}
}

}
}

Now you've finished making a rigidchips model. The finished model should be this:

Code:


Val
{
Engine(default=0,min=-3000,max=5000,step=1000)
Brake(default=0,min=0,max=100,step=50)
Steering(default=0,min=-15,max=15,step=1)
}
Key
{
0:Engine(step=500)
1:Engine(step=-500)
2:Steering(step=-0.5)
3:Steering(step=0.5)
4:Brake(step=50)
}
Body {
Core(){

S:Chip(){
E:Trim(angle=-25){
N:Frame(angle=145,damper=0.07,spring=0.07){
E:Wheel(angle=-90,power=-Engine,brake=Brake){

}
}
}
W:Trim(angle=25){
N:Frame(angle=145,damper=0.07,spring=0.07){
W:Wheel(angle=-90,power=Engine,brake=Brake){

}
}
}
}

N:Chip(){
N:Rudder(angle=steering){

E:Trim(angle=-25){
N:Frame(angle=145,damper=0.07,spring=0.07){
E:Wheel(angle=-90,power=-Engine,brake=Brake){

}
}
}
W:Trim(angle=25){
N:Frame(angle=145,damper=0.07,spring=0.07){
W:Wheel(angle=-90,power=Engine,brake=Brake){

}
}
}

}
}

}
}

I hope this helps people get started with making rigidchips models.

I must be retarded... I don't understand any of this...

Nuuuuuuu you took mah tutorial! Meanieeee!!!

Also No.AD8 I'm working on a video based tutorial for you since this reading seems to be your downpoint in learning, please no offence. I'm the same way. 14/100 verbal, 95/100 hands on, so you can see schools a problem xD
Hope it helps, and I hope I can get it done by tommorow or the weekend!

Edit; AD8 try reading it and working in rcd at the same time, you may find you match thoughts on how it works.

Runner wrote:Nuuuuuuu you took mah tutorial! Meanieeee!!!

Also No.AD8 I'm working on a video based tutorial for you since this reading seems to be your downpoint in learning, please no offence. I'm the same way. 14/100 verbal, 95/100 hands on, so you can see schools a problem xD
Hope it helps, and I hope I can get it done by tommorow or the weekend!

Edit; AD8 try reading it and working in rcd at the same time, you may find you match thoughts on how it works.

Yeah i am hands on lol i will try

@Runner: Okay, that's your tutorial? If it is, I'll edit the post to give you credit.

@No.AD8: Please don't quote the post above you...
This tutorial explains how to make a model in notepad using text only. In my opinion, it is key to learn how to make a model from scratch before learning RCD, because you'll understand a lot more.

@fredsmith Sorry...

Any way I GOT SOME THING TO WORK!!!!

p.s how do i make Engines accelerate to top speed instantly?

In the Key VAL{} make the step the same as the ENGINE VALs max.

@Fred This is not my tutorial but it was one I was making, you just posted it becore I finshed mine. lol
Oh, and fred, like in my previous post, some people are visual learners than readers, so it'll be good to have both up.

@AD8 Like Shade said, in the key tab use the same number as the maximum number you set Engine to in the Val tab.

Thanks guys!

Yeah... I agree that it's hard to learn stuff in RC when just reading about it. A video tutorial would be fantastic.

Working on a picture based explination, and the video. I'll re-do the video and add voice to it later. But for now, I'll just use text. =D

lol. Okay. Sounds good.

fuck im confused